Imports LibUsbDotNet
Imports LibUsbDotNet.Main
Imports System.Diagnostics
Imports System.Runtime.InteropServices
Imports System.Threading

Public Interface IUniComm
    Sub Init()
    Function Connect() As Boolean
    Sub Disconnect()
    Function Read(ByRef DBuffer() As Byte, ByVal DOffset As Int32, ByVal MaxBytes As Int32) As Int32
    Function Write(ByRef DBuffer() As Byte, ByVal DOffset As Int32, ByVal NumBytes As Int32) As Boolean
    ReadOnly Property RXDataCount As Int32
    ReadOnly Property TXFreeSpace As Int32
    Event DataReceived()
End Interface

Public Class USBGen_LibUSB
    Implements IUniComm
    Implements IDisposable

    Public Const RXFIFOSIZE As Int32 = 65536
    Public Const TXFIFOSIZE As Int32 = 65536

    Public DevVID As Int32 = Int32.MaxValue
    Public DevPID As Int32 = Int32.MaxValue
    Public DevRevision As Int32 = Int32.MaxValue
    Public DevSerialNumber As String = String.Empty
    Public DevGUID As Guid = Guid.Empty

    Public Event DataReceived() Implements IUniComm.DataReceived

    Private MyUSBDevice As UsbDevice
    Private MyUSBDeviceFinder As UsbDeviceFinder
    Private WholeUSBDevice As IUsbDevice
    Private MyUSBWriter As UsbEndpointWriter
    Private WithEvents MyUSBReader As UsbEndpointReader
    Private MyUSBSetupPacket As UsbSetupPacket

    Private RXFIFO(RXFIFOSIZE - 1) As Byte
    Private RXReadPos As Int32
    Private RXWritePos As Int32

    Private TXFIFO(TXFIFOSIZE - 1) As Byte
    Private TXReadPos As Int32
    Private TXWritePos As Int32

    Private bkThread As Threading.Thread
    Private bkThExit As Boolean

    Public Function Connect() As Boolean Implements IUniComm.Connect
        Dim rv As Boolean
        rv = False
        Disconnect()
        MyUSBDeviceFinder = New UsbDeviceFinder(DevVID, DevPID, DevRevision, DevSerialNumber, DevGUID)
        MyUSBDevice = UsbDevice.OpenUsbDevice(MyUSBDeviceFinder)
        If MyUSBDevice IsNot Nothing Then
            WholeUsbDevice = TryCast(MyUSBDevice, IUsbDevice)
            If Not ReferenceEquals(WholeUsbDevice, Nothing) Then
                WholeUsbDevice.SetConfiguration(1)
                WholeUsbDevice.ClaimInterface(0)
            End If
            MyUSBWriter = MyUSBDevice.OpenEndpointWriter(WriteEndpointID.Ep01)
            MyUSBReader = MyUSBDevice.OpenEndpointReader(ReadEndpointID.Ep02, 4096)
            MyUSBReader.DataReceivedEnabled = True
            With MyUSBSetupPacket
                .RequestType = UsbCtrlFlags.RequestType_Vendor Or UsbCtrlFlags.Recipient_Interface Or UsbCtrlFlags.Direction_In
                .Request = 1
                .Value = 0
                .Length = 4
            End With
            bkThread = New Threading.Thread(AddressOf Me.Th_DoWork)
            bkThExit = False
            bkThread.Start()
            rv = True
        End If
        Return rv
    End Function

    Public Sub Disconnect() Implements IUniComm.Disconnect
        If bkThread IsNot Nothing Then
            bkThExit = True
            bkThread.Interrupt()
            If bkThread.ThreadState = Threading.ThreadState.Running Then bkThread.Join()
        End If
        bkThread = Nothing
        If MyUSBDevice IsNot Nothing Then
            If MyUSBDevice.IsOpen Then
                WholeUSBDevice = TryCast(MyUSBDevice, IUsbDevice)
                If Not ReferenceEquals(WholeUSBDevice, Nothing) Then
                    WholeUSBDevice.ReleaseInterface(0)
                End If
                MyUSBReader.DataReceivedEnabled = False
                MyUSBDevice.Close()
            End If
            MyUSBDevice = Nothing
            WholeUSBDevice = Nothing
            MyUSBDeviceFinder = Nothing
            MyUSBReader = Nothing
            MyUSBWriter = Nothing
        End If
    End Sub

    Public Sub Init() Implements IUniComm.Init
        Disconnect()
        RXReadPos = 0
        RXWritePos = 0
        DevVID = Int32.MaxValue
        DevPID = Int32.MaxValue
        DevRevision = Int32.MaxValue
        DevGUID = Guid.Empty
    End Sub

    Public ReadOnly Property RXDataCount As Int32 Implements IUniComm.RXDataCount
        Get
            Dim i As Int32
            i = RXWritePos - RXReadPos
            If i < 0 Then i += RXFIFOSIZE
            Return i
        End Get
    End Property

    Public Function Read(ByRef DBuffer() As Byte, ByVal DOffset As Int32, ByVal MaxBytes As Int32) As Int32 Implements IUniComm.Read
        Dim i As Int32
        If MaxBytes < 0 Then MaxBytes = 0
        If MaxBytes > 0 Then
            i = RXDataCount
            If MaxBytes > i Then MaxBytes = i
            While i > 0
                DBuffer(DOffset) = RXFIFO(RXReadPos)
                DOffset += 1
                RXReadPos = (RXReadPos + 1) Mod RXFIFOSIZE
                i -= 1
            End While
        End If
        Return MaxBytes
    End Function

    Public ReadOnly Property TXFreeSpace As Int32 Implements IUniComm.TXFreeSpace
        Get
            Dim i As Int32
            i = TXWritePos - TXReadPos
            If i < 0 Then i += TXFIFOSIZE
            i = TXFIFOSIZE - i
            Return i
        End Get
    End Property

    Public Function Write(ByRef DBuffer() As Byte, ByVal DOffset As Integer, ByVal NumBytes As Integer) As Boolean Implements IUniComm.Write
        Dim i As Int32
        If NumBytes > TXFreeSpace Then Throw New Exception("Not enough space in TX buffer.")
        For i = 0 To NumBytes - 1
            TXFIFO(TXWritePos) = DBuffer(DOffset + i)
            TXWritePos = (TXWritePos + 1) Mod TXFIFOSIZE
        Next
        If bkThread IsNot Nothing Then bkThread.Interrupt() 'Wake up the writing thread if asleep
        Debug.Print("Data sent: (" & i & " of " & NumBytes & " byte(s) )")
        Return True
    End Function


    Public Sub Dispose() Implements IDisposable.Dispose
        Disconnect()
    End Sub

    Private Sub MyUSBReader_DataReceived(sender As Object, e As LibUsbDotNet.Main.EndpointDataEventArgs) Handles MyUSBReader.DataReceived
        Dim i As Int32
        Dim s As String
        Debug.Print("SSCOMM: Received " & e.Count & " byte(s):")
        If e.Count > 0 Then
            If RXDataCount + e.Count < RXFIFOSIZE Then
                s = ""
                For i = 0 To e.Count - 1
                    s = s & e.Buffer(i) & " "
                    RXFIFO(RXWritePos) = e.Buffer(i)
                    RXWritePos = (RXWritePos + 1) Mod RXFIFOSIZE
                Next i
                Debug.Print(s)
            Else
                Throw New Exception("RX FIFO overflow")
            End If
            RaiseEvent DataReceived()
        End If
    End Sub
    Private Sub Th_DoWork()
        Dim lDevMaxDataSize As Int32
        Dim lDevWait As Int32
        Dim lTXSize As Int32
        Dim i(0) As Int32
        Try
            While (True)
                If TXReadPos <> TXWritePos Then

                    lDevWait += 1
                    If lDevWait > 1000 Then lDevWait = 1000

                    If MyUSBDevice IsNot Nothing Then
                        If MyUSBDevice.IsOpen Then
                            If MyUSBWriter IsNot Nothing Then
                                If MyUSBDevice.ControlTransfer(MyUSBSetupPacket, i, 4, lTXSize) Then 'query how much data device can accept
                                    If lTXSize = 4 Then
                                        lDevMaxDataSize = i(0)
                                        Debug.Print("Device can accept maximum " & lDevMaxDataSize & " byte(s)")
                                        If lDevMaxDataSize > 0 Then
                                            lDevWait = 0
                                            lTXSize = TXWritePos - TXReadPos
                                            If lTXSize < 0 Then lTXSize += TXFIFOSIZE
                                            If lTXSize > 0 Then
                                                If lTXSize > lDevMaxDataSize Then lTXSize = lDevMaxDataSize
                                                If (TXReadPos + lTXSize) > TXFIFOSIZE Then lTXSize = TXFIFOSIZE - TXReadPos + 1
                                                If MyUSBWriter.Write(TXFIFO, TXReadPos, lTXSize, 2000, lTXSize) = ErrorCode.Success Then
                                                    TXReadPos = (TXReadPos + lTXSize) Mod TXFIFOSIZE
                                                End If
                                            End If
                                        End If
                                    End If
                                End If
                            End If
                        End If
                    End If
                    Try
                        Threading.Thread.Sleep(lDevWait)
                    Catch ie As Threading.ThreadInterruptedException
                        Exit Try
                    End Try
                Else 'there is nothing to send. Go to sleep till something gets written to TXFIFO
                    Try
                        Threading.Thread.Sleep(Timeout.Infinite)
                    Catch ie As Threading.ThreadInterruptedException
                        Exit Try
                    End Try
                End If
                If bkThExit Then Exit While
            End While
        Catch x As Threading.ThreadAbortException
            Exit Try
        End Try
    End Sub

End Class